Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames

Relics.RelicStrengthInventory


00001
00002
00003
00004
00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
class RelicStrengthInventory expands RelicInventory;

#exec MESH IMPORT MESH=RelicStrength ANIVFILE=MODELS\RelicStrength_a.3d DATAFILE=MODELS\RelicStrength_d.3d X=0 Y=0 Z=0 MLOD=0.5
#exec MESH ORIGIN MESH=RelicStrength X=0 Y=0 Z=0
#exec MESH SEQUENCE MESH=RelicStrength SEQ=All                      STARTFRAME=0 NUMFRAMES=1
#exec MESH SEQUENCE MESH=RelicStrength SEQ=base                     STARTFRAME=0 NUMFRAMES=1
#exec MESHMAP NEW   MESHMAP=RelicStrength MESH=RelicStrength
#exec MESHMAP SCALE MESHMAP=RelicStrength X=0.1 Y=0.1 Z=0.2
#exec TEXTURE IMPORT NAME=JRelicStrength_01 FILE=Textures\RelicStrength.PCX GROUP=Skins FLAGS=2	//Material #1
#exec MESHMAP SETTEXTURE MESHMAP=RelicStrength NUM=1 TEXTURE=JRelicStrength_01

#exec AUDIO IMPORT FILE="Sounds\StrengthUse.WAV" NAME="StrengthUse" GROUP="Relics"

var float FireTime;
var TournamentWeapon StrengthWeapon;

function bool HandlePickupQuery( inventory Item )
{
    if (Item.IsA('UDamage'))
        return true;
    else
        return Super.HandlePickupQuery( Item );
}

function PickupFunction(Pawn Other)
{
    local Inventory I;
    
    Super.PickupFunction(Other);

    // remove any damage amplifiers
    for ( I=Owner.Inventory; I!=None; I=I.Inventory )
        if ( I.IsA('UDamage') )
        {
            I.SetTimer(0.2, false);
            UDamage(I).FinalCount = 0;
        }
}

state Activated
{
    function BeginState()
    {
        Pawn(Owner).DamageScaling = 2.0;
        SetStrengthWeapon();
        Super.BeginState();
    }

    function EndState()
    {
        Pawn(Owner).DamageScaling = 1.0;
        if (  StrengthWeapon != None )
            StrengthWeapon.Affector = None;
        Super.EndState();
    }
}

function SetStrengthWeapon()
{
    // Make old weapon normal again.
    if ( StrengthWeapon != None )
        StrengthWeapon.Affector = None;

    StrengthWeapon = TournamentWeapon(Pawn(Owner).Weapon);

    if ( StrengthWeapon != None )
        StrengthWeapon.Affector = self;
}

function ChangedWeapon()
{
    if( Inventory != None )
        Inventory.ChangedWeapon();

    SetStrengthWeapon();
}

simulated function FireEffect()
{
    SetLocation(Owner.Location);
    SetBase(Owner);
    PlaySound(sound'StrengthUse', SLOT_Interact, 6);
    PlaySound(sound'StrengthUse', SLOT_Interact, 6);
    FlashShell(0.15);
}

defaultproperties
{
     ShellSkin=Texture'Relics.Skins.RelicPurple'
     PickupMessage="You picked up the Relic of Strength!"
     PickupViewMesh=Mesh'Relics.RelicStrength'
     PickupViewScale=0.700000
     Icon=Texture'Relics.Icons.RelicIconStrength'
     Physics=PHYS_Rotating
     Texture=Texture'Relics.Skins.JRelicStrength_01'
     Skin=Texture'Relics.Skins.JRelicStrength_01'
     CollisionHeight=40.000000
     LightHue=185
     LightSaturation=0
}

Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames
Class file time: So 5.12.2004 09:34:48.000 - Creation time: Fr 7.6.2013 13:15:55.351 - Created with UnCodeX