de.TBMutator

//=============================================================================
// TBMutator. 
// Steve Sinclair, Digital Extremes, Jan 4, 2000
// originally this was going to be a HUD mutation
// but using actual sprites worked better than overlays
// I stayed with the HUDmutator paradigm because it was the easiest
// way for me to hook this into network clients and might also
// be complimented by some more PostRender action
//=============================================================================
class TBMutator expands Mutator;

var float           mMinScale;
var float           mMaxScale;
var PlayerPawn      PlayerOwner;

// sets the sprite's texture based on team id
simulated function SetSymbol( IdentitySymbol s, byte team)
{
    switch (team)
    {
        case 0:
            s.Texture = texture'TSignR';
            break;
        case 1:
            s.Texture = texture'TSignB';
            break;
        case 2:
            s.Texture = texture'TSignG';
            break;
        case 3:
            s.Texture = texture'TSignY';
            break;
        default:
            s.Texture = texture'TSignR';
    }
}

simulated function PostRender(Canvas canvas)
{
    PlayerOwner = Canvas.Viewport.Actor;
    // call the next HUDmutator
    if ( NextMutator != None )
    {
         NextMutator.PostRender(Canvas);
    }
}

simulated function Tick(float Delta)
{
    local Pawn      P;
    local float     dist;
    local Vector    dir;
    local Vector    loc;
    local byte      team_id;
    local int       num_used;
    local int       player_id;
    local int       team_count;
    local int       symbol_count;
    local float     draw_scale;
    local float     interp;
    
    local PlayerReplicationInfo PRI;
    local IdentitySymbol s;

    if (PlayerOwner == None)// || !PlayerOwner.Level.Game.bTeamGame)
    {
        return;
    }

    // get the player's information
    team_id = PlayerOwner.PlayerReplicationInfo.Team;
    player_id = PlayerOwner.PlayerReplicationInfo.PlayerID;
    
    num_used = 0;
    team_count = 0;
    symbol_count = 0;
    // count the symbols in the client environment and set them available
    foreach AllActors (class 'IdentitySymbol', s)
    {
        symbol_count++;
        s.bHidden = True; // we use this to set the symbol as 'available' for assignment
    }

    // cycle through the Pawns and assign symbols to team mates
    // this is far from the optimal way to do it
    foreach AllActors (class'Pawn', P)
    {
        PRI = P.PlayerReplicationInfo;
        if ( PRI == None )
            continue;
        if ( team_id == PRI.Team && player_id != PRI.PlayerID)
        {
            team_count++;
            if (team_count > symbol_count)// spawn if need more
            {
                s = Spawn(class 'IdentitySymbol', P);
                s.bHidden = P.bHidden;
                s.SetOwner(P);
                symbol_count++;
            }
            else // otherwise, assign a free IdentitySymbol to someone
            {
                foreach AllActors (class 'IdentitySymbol', s)
                {
                    if (s.bHidden == True)
                    {
                        s.bHidden = P.bHidden;
                        s.SetOwner(P);
                        break;
                    }
                }
            }

            // set sprite location above their head
            loc = P.Location;
            loc.z += P.CollisionHeight * 1.75;
            // interp from min/max view distance, to scale the sprite based on distance
            dir = P.Location - PlayerOwner.Location;
            dist = VSize(Dir);
            interp = Dist/32768.0;
        
            // adjust sprite scale if zooming :kludged values:
            interp -= 0.3 * (1.0-(PlayerOwner.FOVAngle / PlayerOwner.DesiredFOV));
            // clamp
            if (interp < 0.0)
                interp = 0.0;
            if (interp > 1.0)
                interp = 1.0;
            draw_scale = Lerp( interp, mMinScale, mMaxScale); 
            s.SetLocation(loc);
            s.DrawScale = draw_scale;
            SetSymbol(s, team_id); // update the texture
        }
    }
}

defaultproperties
{
     mMinScale=0.300000
     mMaxScale=14.000000
}