de.TBNotify

// TBNotify.
// Steve Sinclair, Digital Extremes, Jan 4, 2000 (Sept 5,2000)

class TBNotify expands SpawnNotify;

//Called automatically anytime the class you specified in default properites
// is spawned (also called if a subclass of that class is spawned).
//Great way to catch things to modify or replace them - just make sure to use
// if statements to avoid infinite recursion if you replace something by
// spawning a new subclass.

simulated event Actor SpawnNotification( Actor A )
{
    local Mutator tempActor;    
    if ( HUD(A).HUDMutator == none ) 
    {
        //If there aren't any HUDMutators attached to the HUD, attach
        // your mutator.
        HUD(A).HUDMutator = spawn(class'TBMutator',A);
    }
    else
    {
        //If there is a HUDMutator attached to the HUD already, call
        // AddMutator on that hud, passing it a newly spawned mutator
        // of your own. Note that the AddMutator function will
        // automatically seek the end of the mutator chain. (If the
        // one you try to add yourself to has a NextMutator, the
        // function call is passed to that mutator.)
        HUD(A).HUDMutator.AddMutator(spawn(class'TBMutator',A));
    }
    
    //Have to return the original actor (the HUD). If we had
    // completely replaced it we would return the replacement.
    return A;
}

defaultproperties
{
     ActorClass=Class'Engine.HUD'
}