Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames

UWindow.UWindowFramedWindow


00001
00002
00003
00004
00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
//=============================================================================
// UWindowFramedWindow - a Windows95 style framed window
//=============================================================================
class UWindowFramedWindow extends UWindowWindow;


var class<UWindowWindow>    ClientClass;
var UWindowWindow           ClientArea;
var localized string        WindowTitle;
var string                  StatusBarText;
var float                   MoveX, MoveY;   // co-ordinates where the move was requested
var float                   MinWinWidth, MinWinHeight;

var bool                    bTLSizing;
var bool                    bTSizing;
var bool                    bTRSizing;
var bool                    bLSizing;
var bool                    bRSizing;
var bool                    bBLSizing;
var bool                    bBSizing;
var bool                    bBRSizing;

var bool                    bMoving;
var bool                    bSizable;
var bool                    bStatusBar;
var UWindowFrameCloseBox    CloseBox;


function Created()
{
    Super.Created();

    MinWinWidth = 50;
    MinWinHeight = 50;
    ClientArea = CreateWindow(ClientClass, 4, 16, WinWidth - 8, WinHeight - 20, OwnerWindow);
    CloseBox = UWindowFrameCloseBox(CreateWindow(Class'UWindowFrameCloseBox', WinWidth-20, WinHeight-20, 11, 10));
}

function Texture GetLookAndFeelTexture()
{
    return LookAndFeel.GetTexture(Self);
}

function bool IsActive()
{
    return ParentWindow.ActiveWindow == Self;
}

function BeforePaint(Canvas C, float X, float Y)
{   
    Super.BeforePaint(C, X, Y);
    Resized();
    LookAndFeel.FW_SetupFrameButtons(Self, C);
}

function Paint(Canvas C, float X, float Y)
{
    LookAndFeel.FW_DrawWindowFrame(Self, C);
}

function LMouseDown(float X, float Y)
{
    local FrameHitTest H;
    H = LookAndFeel.FW_HitTest(Self, X, Y);

    Super.LMouseDown(X, Y);


    if(H == HT_TitleBar)
    {
        MoveX = X;
        MoveY = Y;
        bMoving = True;
        Root.CaptureMouse();

        return;
    }

    if(bSizable) 
    {
        switch(H)
        {
        case HT_NW:
            bTLSizing = True;
            Root.CaptureMouse();
            return;
        case HT_NE:
            bTRSizing = True;
            Root.CaptureMouse();
            return;
        case HT_SW:
            bBLSizing = True;
            Root.CaptureMouse();
            return;     
        case HT_SE:
            bBRSizing = True;
            Root.CaptureMouse();
            return;
        case HT_N:
            bTSizing = True;
            Root.CaptureMouse();
            return;
        case HT_S:
            bBSizing = True;
            Root.CaptureMouse();
            return;
        case HT_W:
            bLSizing = True;
            Root.CaptureMouse();
            return;
        case HT_E:
            bRSizing = True;
            Root.CaptureMouse();
            return;
        }
    }
}

function Resized()
{
    local Region R;

    if(ClientArea == None)
    {
        Log("Client Area is None for "$Self);
        return;
    }

    R = LookAndFeel.FW_GetClientArea(Self);

    ClientArea.WinLeft = R.X;
    ClientArea.WinTop = R.Y;

    if((R.W != ClientArea.WinWidth) || (R.H != ClientArea.WinHeight)) 
    {
        ClientArea.SetSize(R.W, R.H);
    }

}

function MouseMove(float X, float Y)
{
    local float OldW, OldH;
    local FrameHitTest H;
    H = LookAndFeel.FW_HitTest(Self, X, Y);


    if(bMoving && bMouseDown)
    {
        WinLeft = Int(WinLeft + X - MoveX);
        WinTop = Int(WinTop + Y - MoveY);
    }
    else
        bMoving = False;


    Cursor = Root.NormalCursor;

    if(bSizable && !bMoving)
    {
        switch(H)
        {
        case HT_NW:
        case HT_SE:
            Cursor = Root.DiagCursor1;
            break;
        case HT_NE:
        case HT_SW:
            Cursor = Root.DiagCursor2;
            break;
        case HT_W:
        case HT_E:
            Cursor = Root.WECursor;
            break;
        case HT_N:
        case HT_S:
            Cursor = Root.NSCursor;
            break;
        }
    }   

    // Top Left
    if(bTLSizing && bMouseDown)
    {
        Cursor = Root.DiagCursor1;  
        OldW = WinWidth;
        OldH = WinHeight;
        SetSize(Max(MinWinWidth, WinWidth - X), Max(MinWinHeight, WinHeight - Y));
        WinLeft = Int(WinLeft + OldW - WinWidth);
        WinTop = Int(WinTop + OldH - WinHeight);
    }
    else 
        bTLSizing = False;


    // Top
    if(bTSizing && bMouseDown)
    {
        Cursor = Root.NSCursor;
        OldH = WinHeight;
        SetSize(WinWidth, Max(MinWinHeight, WinHeight - Y));
        WinTop = Int(WinTop + OldH - WinHeight);
    }
    else 
        bTSizing = False;

    // Top Right
    if(bTRSizing && bMouseDown)
    {
        Cursor = Root.DiagCursor2;
        OldH = WinHeight;
        SetSize(Max(MinWinWidth, X), Max(MinWinHeight, WinHeight - Y));
        WinTop = Int(WinTop + OldH - WinHeight);
    }
    else 
        bTRSizing = False;


    // Left
    if(bLSizing && bMouseDown)
    {
        Cursor = Root.WECursor;
        OldW = WinWidth;
        SetSize(Max(MinWinWidth, WinWidth - X), WinHeight);
        WinLeft = Int(WinLeft + OldW - WinWidth);
    }
    else 
        bLSizing = False;

    // Right
    if(bRSizing && bMouseDown)
    {
        Cursor = Root.WECursor;
        SetSize(Max(MinWinWidth, X), WinHeight);
    }
    else 
        bRSizing = False;

    // Bottom Left
    if(bBLSizing && bMouseDown)
    {
        Cursor = Root.DiagCursor2;
        OldW = WinWidth;
        SetSize(Max(MinWinWidth, WinWidth - X), Max(MinWinHeight, Y));
        WinLeft = Int(WinLeft + OldW - WinWidth);
    }
    else 
        bBLSizing = False;

    // Bottom
    if(bBSizing && bMouseDown)
    {
        Cursor = Root.NSCursor;
        SetSize(WinWidth, Max(MinWinHeight, Y));
    }
    else 
        bBSizing = False;

    // Bottom Right
    if(bBRSizing && bMouseDown)
    {
        Cursor = Root.DiagCursor1;
        SetSize(Max(MinWinWidth, X), Max(MinWinHeight, Y));
    }
    else
        bBRSizing = False;

}

function ToolTip(string strTip)
{
    StatusBarText = strTip;
}

function WindowEvent(WinMessage Msg, Canvas C, float X, float Y, int Key) 
{
    if(Msg == WM_Paint || !WaitModal())
        Super.WindowEvent(Msg, C, X, Y, Key);
}

function WindowHidden()
{
    Super.WindowHidden();
    LookAndFeel.PlayMenuSound(Self, MS_WindowClose);
}

defaultproperties
{
     ClientClass=Class'UWindow.UWindowClientWindow'
}

Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames
Class file time: Do 19.5.2005 19:42:12.000 - Creation time: Fr 7.6.2013 13:16:24.414 - Created with UnCodeX