Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames

UMenu.UMenuVideoClientWindow


00001
00002
00003
00004
00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
00422
00423
00424
00425
00426
00427
00428
00429
00430
00431
00432
00433
00434
00435
00436
00437
00438
00439
00440
00441
00442
00443
00444
00445
00446
00447
00448
00449
00450
00451
00452
00453
00454
00455
00456
00457
00458
00459
00460
00461
00462
00463
00464
00465
00466
00467
00468
00469
00470
00471
00472
00473
00474
00475
00476
00477
00478
00479
00480
00481
00482
00483
00484
00485
00486
00487
00488
00489
00490
00491
00492
00493
00494
00495
00496
00497
00498
00499
00500
00501
00502
00503
00504
00505
00506
00507
00508
00509
00510
00511
00512
00513
00514
00515
00516
00517
00518
00519
00520
00521
00522
00523
00524
00525
00526
00527
00528
00529
00530
00531
00532
00533
00534
00535
00536
00537
00538
00539
00540
00541
00542
00543
00544
00545
00546
00547
00548
00549
00550
00551
00552
00553
00554
00555
00556
00557
00558
00559
00560
00561
00562
00563
00564
00565
00566
00567
00568
00569
00570
00571
00572
00573
00574
00575
00576
00577
00578
00579
00580
00581
00582
00583
00584
00585
00586
00587
00588
00589
00590
00591
00592
00593
00594
00595
00596
00597
00598
00599
00600
00601
00602
00603
00604
00605
00606
00607
00608
00609
00610
00611
00612
00613
00614
00615
00616
00617
00618
00619
00620
00621
00622
00623
00624
00625
00626
00627
00628
00629
00630
00631
00632
00633
00634
00635
class UMenuVideoClientWindow extends UMenuPageWindow;

// Driver
var bool bInitialized;
var UWindowLabelControl DriverLabel;
var UWindowLabelControl DriverDesc;
var UWindowSmallButton DriverButton;
var localized string DriverText;
var localized string DriverHelp;
var localized string DriverButtonText;
var localized string DriverButtonHelp;

// Resolution
var UWindowComboControl ResolutionCombo;
var localized string ResolutionText;
var localized string ResolutionHelp;

var string OldSettings;

// Color Depth
var UWindowComboControl ColorDepthCombo;
var localized string ColorDepthText;
var localized string ColorDepthHelp;
var localized string BitsText;

// Texture Detail
var UWindowComboControl TextureDetailCombo;
var localized string TextureDetailText;
var localized string TextureDetailHelp;
var localized string Details[3];
var int OldTextureDetail;

// Skin Detail
var UWindowComboControl SkinDetailCombo;
var localized string SkinDetailText;
var localized string SkinDetailHelp;
var int OldSkinDetail;

// Brightness
var UWindowHSliderControl BrightnessSlider;
var localized string BrightnessText;
var localized string BrightnessHelp;

// GUI Scale
var UWindowComboControl ScaleCombo;
var localized string ScaleText;
var localized string ScaleHelp;

var localized string ScaleSizes[2];

// Mouse Speed
var UWindowHSliderControl MouseSlider;
var localized string MouseText;
var localized string MouseHelp;

// GUI Skin
var UWindowComboControl GuiSkinCombo;
var localized string GuiSkinText;
var localized string GuiSkinHelp;

var float ControlOffset;

var UWindowMessageBox ConfirmSettings, ConfirmDriver, ConfirmWorldTextureDetail, ConfirmSkinTextureDetail;
var localized string ConfirmSettingsTitle;
var localized string ConfirmSettingsText;
var localized string ConfirmSettingsCancelTitle;
var localized string ConfirmSettingsCancelText;
var localized string ConfirmTextureDetailTitle;
var localized string ConfirmTextureDetailText;
var localized string ConfirmDriverTitle;
var localized string ConfirmDriverText;

// Show Decals
var UWindowCheckbox ShowDecalsCheck;
var localized string ShowDecalsText;
var localized string ShowDecalsHelp;

// Min Desired Frame Rate
var UWindowEditControl MinFramerateEdit;
var localized string MinFramerateText;
var localized string MinFramerateHelp;

// Dynamic Lights
var UWindowCheckbox DynamicLightsCheck;
var localized string DynamicLightsText;
var localized string DynamicLightsHelp;

function Created()
{
    local bool bLowSoundQuality;
    local int MusicVolume, SoundVolume;
    local int ControlWidth, ControlLeft, ControlRight;
    local int CenterWidth, CenterPos;
    local int i, MinRate;
    local string NextLook, NextDesc;
    local string VideoDriverClassName, ClassLeft, ClassRight, VideoDriverDesc;

    Super.Created();

    ControlWidth = WinWidth/2.5;
    ControlLeft = (WinWidth/2 - ControlWidth)/2;
    ControlRight = WinWidth/2 + ControlLeft;

    CenterWidth = (WinWidth/4)*3;
    CenterPos = (WinWidth - CenterWidth)/2;
    
    VideoDriverClassName = GetPlayerOwner().ConsoleCommand("get ini:Engine.Engine.GameRenderDevice Class");
    i = InStr(VideoDriverClassName, "'");
    // Get class name from class'...'
    if(i != -1)
    {
        VideoDriverClassName = Mid(VideoDriverClassName, i+1);
        i = InStr(VideoDriverClassName, "'");
        VideoDriverClassName = Left(VideoDriverClassName, i);
        ClassLeft = Left(VideoDriverClassName, InStr(VideoDriverClassName, "."));
        ClassRight = Mid(VideoDriverClassName, InStr(VideoDriverClassName, ".") + 1);
        VideoDriverDesc = Localize(ClassRight, "ClassCaption", ClassLeft);
    }
    else
        VideoDriverDesc = "VideoDriverClassName";

    // Driver
    DriverLabel = UWindowLabelControl(CreateControl(class'UWindowLabelControl', ControlLeft, ControlOffset, ControlWidth, 1));
    DriverLabel.SetText(DriverText);
    DriverLabel.SetHelpText(DriverHelp);
    DriverLabel.SetFont(F_Normal);

    DriverDesc = UWindowLabelControl(CreateControl(class'UWindowLabelControl', ControlRight, ControlOffset, ControlWidth, 1));
    DriverDesc.SetText(VideoDriverDesc);
    DriverDesc.SetHelpText(DriverHelp);
    DriverDesc.SetFont(F_Normal);
    ControlOffset += 17;

    DriverButton = UWindowSmallButton(CreateControl(class'UWindowSmallButton', ControlRight, ControlOffset, 48, 16));
    DriverButton.SetText(DriverButtonText);
    DriverButton.SetFont(F_Normal);
    DriverButton.SetHelpText(DriverButtonHelp);
    ControlOffset += 25;


    // Resolution
    ResolutionCombo = UWindowComboControl(CreateControl(class'UWindowComboControl', CenterPos, ControlOffset, CenterWidth, 1));
    ResolutionCombo.SetText(ResolutionText);
    ResolutionCombo.SetHelpText(ResolutionHelp);
    ResolutionCombo.SetFont(F_Normal);
    ResolutionCombo.SetEditable(False);
    ControlOffset += 25;

    ColorDepthCombo = UWindowComboControl(CreateControl(class'UWindowComboControl', CenterPos, ControlOffset, CenterWidth, 1));
    ColorDepthCombo.SetText(ColorDepthText);
    ColorDepthCombo.SetHelpText(ColorDepthHelp);
    ColorDepthCombo.SetFont(F_Normal);
    ColorDepthCombo.SetEditable(False);
    ControlOffset += 25;

    // Texture Detail
    TextureDetailCombo = UWindowComboControl(CreateControl(class'UWindowComboControl', CenterPos, ControlOffset, CenterWidth, 1));
    TextureDetailCombo.SetText(TextureDetailText);
    TextureDetailCombo.SetHelpText(TextureDetailHelp);
    TextureDetailCombo.SetFont(F_Normal);
    TextureDetailCombo.SetEditable(False);
    ControlOffset += 25;

    // The display names are localized.  These strings match the enums in UnCamMgr.cpp.
    TextureDetailCombo.AddItem(Details[0], "High");
    TextureDetailCombo.AddItem(Details[1], "Medium");
    TextureDetailCombo.AddItem(Details[2], "Low");

    // Skin Detail
    SkinDetailCombo = UWindowComboControl(CreateControl(class'UWindowComboControl', CenterPos, ControlOffset, CenterWidth, 1));
    SkinDetailCombo.SetText(SkinDetailText);
    SkinDetailCombo.SetHelpText(SkinDetailHelp);
    SkinDetailCombo.SetFont(F_Normal);
    SkinDetailCombo.SetEditable(False);
    SkinDetailCombo.AddItem(Details[0], "High");
    SkinDetailCombo.AddItem(Details[1], "Medium");
    SkinDetailCombo.AddItem(Details[2], "Low");
    ControlOffset += 25;

    // Brightness
    BrightnessSlider = UWindowHSliderControl(CreateControl(class'UWindowHSliderControl', CenterPos, ControlOffset, CenterWidth, 1));
    BrightnessSlider.bNoSlidingNotify = True;
    BrightnessSlider.SetRange(2, 10, 1);
    BrightnessSlider.SetText(BrightnessText);
    BrightnessSlider.SetHelpText(BrightnessHelp);
    BrightnessSlider.SetFont(F_Normal);
    ControlOffset += 25;

    // GUI Mouse speed
    MouseSlider = UWindowHSliderControl(CreateControl(class'UWindowHSliderControl', CenterPos, ControlOffset, CenterWidth, 1));
    MouseSlider.bNoSlidingNotify = True;
    MouseSlider.SetRange(40, 500, 5);
    MouseSlider.SetText(MouseText);
    MouseSlider.SetHelpText(MouseHelp);
    MouseSlider.SetFont(F_Normal);
    ControlOffset += 25;

    // GUI Scale
    ScaleCombo = UWindowComboControl(CreateControl(class'UWindowComboControl', CenterPos, ControlOffset, CenterWidth, 1));
    ScaleCombo.SetText(ScaleText);
    ScaleCombo.SetHelpText(ScaleHelp);
    ScaleCombo.SetFont(F_Normal);
    ScaleCombo.SetEditable(False);
    ScaleCombo.AddItem(ScaleSizes[0], "10");
    ScaleCombo.AddItem(ScaleSizes[1], "20");
    ControlOffset += 25;

    GuiSkinCombo = UWindowComboControl(CreateControl(class'UWindowComboControl', CenterPos, ControlOffset, CenterWidth, 1));
    GuiSkinCombo.SetText(GuiSkinText);
    GuiSkinCombo.SetHelpText(GuiSkinHelp);
    GuiSkinCombo.SetFont(F_Normal);
    GuiSkinCombo.SetEditable(False);
    ControlOffset += 25;
    i=0;
    GetPlayerOwner().GetNextIntDesc("UWindowLookAndFeel", 0, NextLook, NextDesc);
    while( (NextLook != "") && (i < 32) )
    {
        GuiSkinCombo.AddItem(NextDesc, NextLook);
        i++;
        GetPlayerOwner().GetNextIntDesc("UWindowLookAndFeel", i, NextLook, NextDesc);
    }
    GuiSkinCombo.Sort();

    // Min Desired Framerate
    MinFramerateEdit = UWindowEditControl(CreateControl(class'UWindowEditControl', CenterPos, ControlOffset, CenterWidth, 1));
    MinFramerateEdit.SetText(MinFramerateText);
    MinFramerateEdit.SetHelpText(MinFramerateHelp);
    MinFramerateEdit.SetFont(F_Normal);
    MinFramerateEdit.SetNumericOnly(True);
    MinFramerateEdit.SetMaxLength(3);
    MinFramerateEdit.Align = TA_Left;
    MinRate = int(GetPlayerOwner().ConsoleCommand("get ini:Engine.Engine.ViewportManager MinDesiredFrameRate"));
    MinFramerateEdit.SetValue(string(MinRate));
    ControlOffset += 25;

    // Show Decals
    ShowDecalsCheck = UWindowCheckbox(CreateControl(class'UWindowCheckbox', CenterPos, ControlOffset, CenterWidth, 1));
    ShowDecalsCheck.bChecked = bool(GetPlayerOwner().ConsoleCommand("get ini:Engine.Engine.ViewportManager Decals"));
    ShowDecalsCheck.SetText(ShowDecalsText);
    ShowDecalsCheck.SetHelpText(ShowDecalsHelp);
    ShowDecalsCheck.SetFont(F_Normal);
    ShowDecalsCheck.Align = TA_Left;
    ControlOffset += 25;

    // Dynamic Lights
    DynamicLightsCheck = UWindowCheckbox(CreateControl(class'UWindowCheckbox', CenterPos, ControlOffset, CenterWidth, 1));
    DynamicLightsCheck.bChecked = bool(GetPlayerOwner().ConsoleCommand("get ini:Engine.Engine.ViewportManager NoDynamicLights"));
    DynamicLightsCheck.bChecked = !DynamicLightsCheck.bChecked;
    DynamicLightsCheck.SetText(DynamicLightsText);
    DynamicLightsCheck.SetHelpText(DynamicLightsHelp);
    DynamicLightsCheck.SetFont(F_Normal);
    DynamicLightsCheck.Align = TA_Left;
    ControlOffset += 25;

    LoadAvailableSettings();
}

function AfterCreate()
{
    Super.AfterCreate();

    DesiredWidth = 220;
    DesiredHeight = ControlOffset;
}

function LoadAvailableSettings()
{
    local float Brightness;
    local int P;
    local string CurrentDepth;
    local string ParseString;

    bInitialized = False;

    // Load available video drivers and current video driver here.

    ResolutionCombo.Clear();
    ParseString = GetPlayerOwner().ConsoleCommand("GetRes");
    P = InStr(ParseString, " ");
    while (P != -1) 
    {
        ResolutionCombo.AddItem(Left(ParseString, P));
        ParseString = Mid(ParseString, P+1);
        P = InStr(ParseString, " ");
    }
    ResolutionCombo.AddItem(ParseString);
    ResolutionCombo.SetValue(GetPlayerOwner().ConsoleCommand("GetCurrentRes"));

    ColorDepthCombo.Clear();
    ParseString = GetPlayerOwner().ConsoleCommand("GetColorDepths");
    P = InStr(ParseString, " ");
    while (P != -1) 
    {
        ColorDepthCombo.AddItem(Left(ParseString, P)@BitsText, Left(ParseString, P));
        ParseString = Mid(ParseString, P+1);
        P = InStr(ParseString, " ");
    }
    ColorDepthCombo.AddItem(ParseString@BitsText, ParseString);
    CurrentDepth = GetPlayerOwner().ConsoleCommand("GetCurrentColorDepth");
    ColorDepthCombo.SetValue(CurrentDepth@BitsText, CurrentDepth);

    GuiSkinCombo.SetSelectedIndex(Max(GuiSkinCombo.FindItemIndex2(Root.LookAndFeelClass, True), 0));
    OldTextureDetail = Max(0, TextureDetailCombo.FindItemIndex2(GetPlayerOwner().ConsoleCommand("get ini:Engine.Engine.ViewportManager TextureDetail")));
    TextureDetailCombo.SetSelectedIndex(OldTextureDetail);
    OldSkinDetail = Max(0, SkinDetailCombo.FindItemIndex2(GetPlayerOwner().ConsoleCommand("get ini:Engine.Engine.ViewportManager SkinDetail")));
    SkinDetailCombo.SetSelectedIndex(OldSkinDetail);
    Brightness = int(float(GetPlayerOwner().ConsoleCommand("get ini:Engine.Engine.ViewportManager Brightness")) * 10);
    BrightnessSlider.SetValue(Brightness);
    MouseSlider.SetValue(Root.Console.MouseScale * 100);
    ScaleCombo.SetSelectedIndex(Max(ScaleCombo.FindItemIndex2(string(int(Root.GUIScale*10))), 0));

    bInitialized = True;
}

function ResolutionChanged(float W, float H)
{
    Super.ResolutionChanged(H, H);
    if(GetPlayerOwner().ConsoleCommand("GetCurrentRes") != ResolutionCombo.GetValue())
        LoadAvailableSettings();
}

function BeforePaint(Canvas C, float X, float Y)
{
    local int ControlWidth, ControlLeft, ControlRight;
    local int CenterWidth, CenterPos;

    Super.BeforePaint(C, X, Y);

    ControlWidth = WinWidth/2.5;
    ControlLeft = (WinWidth/2 - ControlWidth)/2;
    ControlRight = WinWidth/2 + ControlLeft;

    CenterWidth = (WinWidth/4)*3;
    CenterPos = (WinWidth - CenterWidth)/2;

    DriverLabel.SetSize(CenterWidth-100, 1);
    DriverLabel.WinLeft = CenterPos;

    DriverDesc.SetSize(200, 1);
    DriverDesc.WinLeft = CenterPos + CenterWidth - 100;

    DriverButton.AutoWidth(C);
    DriverButton.WinLeft = CenterPos + CenterWidth - 100;

    ResolutionCombo.SetSize(CenterWidth, 1);
    ResolutionCombo.WinLeft = CenterPos;
    ResolutionCombo.EditBoxWidth = 100;

    ColorDepthCombo.SetSize(CenterWidth, 1);
    ColorDepthCombo.WinLeft = CenterPos;
    ColorDepthCombo.EditBoxWidth = 100;

    TextureDetailCombo.SetSize(CenterWidth, 1);
    TextureDetailCombo.WinLeft = CenterPos;
    TextureDetailCombo.EditBoxWidth = 100;

    SkinDetailCombo.SetSize(CenterWidth, 1);
    SkinDetailCombo.WinLeft = CenterPos;
    SkinDetailCombo.EditBoxWidth = 100;

    BrightnessSlider.SetSize(CenterWidth, 1);
    BrightnessSlider.SliderWidth = 100;
    BrightnessSlider.WinLeft = CenterPos;

    ScaleCombo.SetSize(CenterWidth, 1);
    ScaleCombo.WinLeft = CenterPos;
    ScaleCombo.EditBoxWidth = 100;

    MouseSlider.SetSize(CenterWidth, 1);
    MouseSlider.SliderWidth = 100;
    MouseSlider.WinLeft = CenterPos;

    GuiSkinCombo.SetSize(CenterWidth, 1);
    GuiSkinCombo.WinLeft = CenterPos;
    GuiSkinCombo.EditBoxWidth = 100;

    ShowDecalsCheck.SetSize(CenterWidth-100+16, 1);
    ShowDecalsCheck.WinLeft = CenterPos;

    DynamicLightsCheck.SetSize(CenterWidth-100+16, 1);
    DynamicLightsCheck.WinLeft = CenterPos;

    MinFramerateEdit.SetSize(CenterWidth-100+30, 1);
    MinFramerateEdit.WinLeft = CenterPos;
    MinFramerateEdit.EditBoxWidth = 30;
}

function Notify(UWindowDialogControl C, byte E)
{
    Super.Notify(C, E);

    switch(E)
    {
    case DE_Click:
        switch(C)
        {
        case DriverButton:
            DriverChange();
            break;
        }
        break;
    case DE_Change:
        switch(C)
        {
        case ResolutionCombo:
        case ColorDepthCombo:
            SettingsChanged();
            break;
        case TextureDetailCombo:
            TextureDetailChanged();
            break;
        case SkinDetailCombo:
            SkinDetailChanged();
            break;
        case BrightnessSlider:
            BrightnessChanged();
            break;
        case ScaleCombo:
            ScaleChanged();
            break;
        case MouseSlider:
            MouseChanged();
            break;
        case ShowDecalsCheck:
            DecalsChanged();
            break;
        case DynamicLightsCheck:
            DynamicChanged();
            break;
        case MinFramerateEdit:
            MinFramerateChanged();
            break;
        }
        break;
    }
}

/*
 * Message Crackers
 */


function DriverChange()
{
    ConfirmDriver = MessageBox(ConfirmDriverTitle, ConfirmDriverText, MB_YesNo, MR_No);
}

function SettingsChanged()
{
    local string NewSettings;

    if(bInitialized)
    {
        OldSettings = GetPlayerOwner().ConsoleCommand("GetCurrentRes")$"x"$GetPlayerOwner().ConsoleCommand("GetCurrentColorDepth");
        NewSettings = ResolutionCombo.GetValue()$"x"$ColorDepthCombo.GetValue2();

        if(NewSettings != OldSettings)
        {
            GetPlayerOwner().ConsoleCommand("SetRes "$NewSettings);
            LoadAvailableSettings();
            ConfirmSettings = MessageBox(ConfirmSettingsTitle, ConfirmSettingsText, MB_YesNo, MR_No, MR_None, 10);
        }
    }
}

function MessageBoxDone(UWindowMessageBox W, MessageBoxResult Result)
{
    if(W == ConfirmSettings)
    {
        ConfirmSettings = None;
        if(Result != MR_Yes)
        {
            GetPlayerOwner().ConsoleCommand("SetRes "$OldSettings);
            LoadAvailableSettings();            
            MessageBox(ConfirmSettingsCancelTitle, ConfirmSettingsCancelText, MB_OK, MR_OK, MR_OK);
        }
    }
    else
    if(W == ConfirmDriver)
    {
        ConfirmDriver = None;
        if(Result == MR_Yes)
        {
            GetParent(class'UWindowFramedWindow').Close();
            Root.Console.CloseUWindow();
            GetPlayerOwner().ConsoleCommand("RELAUNCH -changevideo");
        }
    }
    if(W == ConfirmSkinTextureDetail)
    {
        if(Result == MR_Yes)
            OldSkinDetail = SkinDetailCombo.GetSelectedIndex();
        else
            SkinDetailCombo.SetSelectedIndex(OldSkinDetail);
    }
    if(W == ConfirmWorldTextureDetail)
    {
        if(Result == MR_Yes)
            OldTextureDetail = TextureDetailCombo.GetSelectedIndex();
        else
            TextureDetailCombo.SetSelectedIndex(OldTextureDetail);
    }
}

function TextureDetailChanged()
{
    if(bInitialized)
    {
        TextureDetailSet();
        if( TextureDetailCombo.GetSelectedIndex() < OldTextureDetail )
            ConfirmWorldTextureDetail = MessageBox(ConfirmTextureDetailTitle, ConfirmTextureDetailText, MB_YesNo, MR_No, MR_None);  
        else
            OldTextureDetail = TextureDetailCombo.GetSelectedIndex();
    }
}

function TextureDetailSet()
{
    GetPlayerOwner().ConsoleCommand("set ini:Engine.Engine.ViewportManager TextureDetail "$TextureDetailCombo.GetValue2());
}

function SkinDetailChanged()
{
    local int D;
    if(bInitialized)
    {
        SkinDetailSet();
        if( SkinDetailCombo.GetSelectedIndex() < OldSkinDetail )
            ConfirmSkinTextureDetail = MessageBox(ConfirmTextureDetailTitle, ConfirmTextureDetailText, MB_YesNo, MR_No, MR_None);   
        else
            OldSkinDetail = SkinDetailCombo.GetSelectedIndex();
    }
}

function SkinDetailSet()
{
    GetPlayerOwner().ConsoleCommand("set ini:Engine.Engine.ViewportManager SkinDetail "$SkinDetailCombo.GetValue2());
}

function BrightnessChanged()
{
    if(bInitialized)
    {
        GetPlayerOwner().ConsoleCommand("set ini:Engine.Engine.ViewportManager Brightness "$(BrightnessSlider.Value / 10));
        GetPlayerOwner().ConsoleCommand("FLUSH");
    }
}

function ScaleChanged()
{
    if(bInitialized)
    {
        Root.SetScale(float(ScaleCombo.GetValue2())/10);
        Root.SaveConfig();
    }
}

function MouseChanged()
{
    if(bInitialized)
    {
        Root.Console.MouseScale = (MouseSlider.Value / 100);
        Root.Console.SaveConfig();
    }
}

function DecalsChanged()
{
    GetPlayerOwner().ConsoleCommand("set ini:Engine.Engine.ViewportManager Decals "$ShowDecalsCheck.bChecked);
}

function DynamicChanged()
{
    GetPlayerOwner().ConsoleCommand("set ini:Engine.Engine.ViewportManager NoDynamicLights "$!DynamicLightsCheck.bChecked);
}

function MinFramerateChanged()
{
    GetPlayerOwner().ConsoleCommand("set ini:Engine.Engine.ViewportManager MinDesiredFrameRate "$MinFramerateEdit.EditBox.Value);
}

function SaveConfigs()
{
    GetPlayerOwner().SaveConfig();
    Root.Console.SaveConfig();
    Super.SaveConfigs();
    if(GuiSkinCombo.GetValue2() != Root.LookAndFeelClass)
        Root.ChangeLookAndFeel(GuiSkinCombo.GetValue2());
}

defaultproperties
{
     DriverText="Video Driver"
     DriverHelp="This is the current video driver.  Use the Change button to change video drivers."
     DriverButtonText="Change"
     DriverButtonHelp="Press this button to change your video driver."
     ResolutionText="Resolution"
     ResolutionHelp="Select a new screen resolution."
     ColorDepthText="Color Depth"
     ColorDepthHelp="Select a new color depth."
     BitsText="bit"
     TextureDetailText="World Texture Detail"
     TextureDetailHelp="Change the texture detail of world geometry.  Use a lower texture detail to improve game performance."
     Details(0)="High"
     Details(1)="Medium"
     Details(2)="Low"
     SkinDetailText="Skin Detail"
     SkinDetailHelp="Change the detail of player skins.  Use a lower skin detail to improve game performance."
     BrightnessText="Brightness"
     BrightnessHelp="Adjust display brightness."
     ScaleText="Font Size"
     ScaleHelp="Adjust the size of elements in the User Interface."
     ScaleSizes(0)="Normal"
     ScaleSizes(1)="Double"
     MouseText="GUI Mouse Speed"
     MouseHelp="Adjust the speed of the mouse in the User Interface."
     GuiSkinText="GUI Skin"
     GuiSkinHelp="Change the look of the User Interface windows to a custom skin."
     ControlOffset=20.000000
     ConfirmSettingsTitle="Confirm Video Settings Change"
     ConfirmSettingsText="Are you sure you wish to keep these new video settings?"
     ConfirmSettingsCancelTitle="Video Settings Change"
     ConfirmSettingsCancelText="Your previous video settings have been restored."
     ConfirmTextureDetailTitle="Confirm Texture Detail"
     ConfirmTextureDetailText="Increasing texture detail above its default value may degrade performance on some machines.\n\nAre you sure you want to make this change?"
     ConfirmDriverTitle="Change Video Driver"
     ConfirmDriverText="This option will restart Unreal now, and enable you to change your video driver.  Do you want to do this?"
     ShowDecalsText="Show Decals"
     ShowDecalsHelp="If checked, impact and gore decals will be used in game."
     MinFramerateText="Min Desired Framerate"
     MinFramerateHelp="If your framerate falls below this value, Unreal Tournament will reduce special effects to increase your framerate."
     DynamicLightsText="Use Dynamic Lighting"
     DynamicLightsHelp="If checked, dynamic lighting will be used in game."
}

Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames
Class file time: Do 19.5.2005 19:42:14.000 - Creation time: Fr 7.6.2013 13:16:15.288 - Created with UnCodeX