Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames

IpServer.UdpServerUplink


00001
00002
00003
00004
00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
//=============================================================================
// UdpServerUplink
//
// Version: 1.3
//
// This uplink is compliant with the GameSpy Uplink Specification.
// The specification is available at http://www.gamespy.com/developer
// and might be of use to progammers who want to adapt their own
// server uplinks.
//
// UdpServerUplink sends a heartbeat to the specified master server
// every five minutes.  The heartbeat is in the form:
//    \heartbeat\QueryPort\gamename\unreal
//
// Full documentation on this class is available at http://unreal.epicgames.com/
//
//=============================================================================
class UdpServerUplink extends UdpLink config;

// Master Uplink Config.
var() config bool       DoUplink;               // If true, do the uplink
var() config int        UpdateMinutes;          // Period of update (in minutes)
var() config string     MasterServerAddress;    // Address of the master server
var() config int        MasterServerPort;       // Optional port that the master server is listening on
var() config int        Region;                 // Region of the game server
var() name              TargetQueryName;        // Name of the query server object to use.
var IpAddr              MasterServerIpAddr;     // Master server's address.
var string              HeartbeatMessage;       // The message that is sent to the master server.
var UdpServerQuery      Query;                  // The query object.
var int                 CurrentQueryNum;        // Query ID Number.

// Initialize.
function PreBeginPlay()
{
    // If master server uplink isn't wanted, exit.
    if( !DoUplink )
    {
        Log("DoUplink is not set.  Not connecting to Master Server.");
        return;
    }

/*
    if( Level.NetMode == NM_ListenServer )
    {
        Log("This is a Listen server.  Not connecting to Master Server.");
        return;
    }
*/

    // Find a the server query handler.
    foreach AllActors(class'UdpServerQuery', Query, TargetQueryName)
        break;

    if( Query==None )
    {
        Log("UdpServerUplink: Could not find a UdpServerQuery object, aborting.");
        return;
    }

    // Set heartbeat message.
    if( MasterServerAddress ~= "unreal.epicgames.com" )
        HeartbeatMessage = "\\heartbeat\\"$Query.Port$"\\gamename\\"$Query.GameName$"\\gamever\\"$Level.EngineVersion;
    else
        HeartbeatMessage = "\\heartbeat\\"$Query.Port$"\\gamename\\"$Query.GameName;

    // Set the Port.
    MasterServerIpAddr.Port = MasterServerPort;

    // Resolve the Address.
    if( MasterServerAddress=="" )
        MasterServerAddress = "master"$Region$".gamespy.com";
    Resolve( MasterServerAddress );
}

// When master server address is resolved.
function Resolved( IpAddr Addr )
{
    local bool Result;
    local int UplinkPort;

    // Set the address
    MasterServerIpAddr.Addr = Addr.Addr;

    // Handle failure.
    if( MasterServerIpAddr.Addr == 0 )
    {
        Log("UdpServerUplink: Invalid master server address, aborting.");
        return;
    }

    // Display success message.
    Log("UdpServerUplink: Master Server is "$MasterServerAddress$":"$MasterServerIpAddr.Port);
    
    // Bind the local port.
    UplinkPort = Query.Port + 1;
    if( BindPort(UplinkPort, true) == 0 )
    {
        Log( "UdpServerUplink: Error binding port, aborting." );
        return;
    }
    Log("UdpServerUplink: Port "$UplinkPort$" successfully bound.");

    // Start transmitting.
    Resume();
}

// Host resolution failue.
function ResolveFailed()
{
    Log("UdpServerUplink: Failed to resolve master server address, aborting.");
}

// Notify the MasterServer we exist.
function Timer()
{
    local bool Result;

    Result = SendText( MasterServerIpAddr, HeartbeatMessage );
    if ( !Result )
        Log( "Failed to send heartbeat to master server.");
}

// Stop the uplink.
function Halt()
{
    SetTimer(0.0, false);
}

// Resume the uplink.
function Resume()
{
    SetTimer(UpdateMinutes * 60, true);
    Timer();
}

// Received a query request.
event ReceivedText( IpAddr Addr, string Text )
{
    local string Query;
    local bool QueryRemaining;
    local int  QueryNum, PacketNum;

    // Assign this packet a unique value from 1 to 100
    CurrentQueryNum++;
    if (CurrentQueryNum > 100)
        CurrentQueryNum = 1;
    QueryNum = CurrentQueryNum;

    Query = Text;
    if (Query == "")        // If the string is empty, don't parse it
        QueryRemaining = false;
    else
        QueryRemaining = true;
    
    while (QueryRemaining) {
        Query = ParseQuery(Addr, Query, QueryNum, PacketNum);
        if (Query == "")
            QueryRemaining = false;
        else
            QueryRemaining = true;
    }
}

function bool ParseNextQuery( string Query, out string QueryType, out string QueryValue, out string QueryRest, out string FinalPacket )
{
    local string TempQuery;
    local int ClosingSlash;

    if (Query == "")
        return false;

    // Query should be:
    //   \[type]\<value>
    if (Left(Query, 1) == "\\")
    {
        // Check to see if closed.
        ClosingSlash = InStr(Right(Query, Len(Query)-1), "\\");
        if (ClosingSlash == 0)
            return false;

        TempQuery = Query;

        // Query looks like:
        //  \[type]\
        QueryType = Right(Query, Len(Query)-1);
        QueryType = Left(QueryType, ClosingSlash);

        QueryRest = Right(Query, Len(Query) - (Len(QueryType) + 2));

        if ((QueryRest == "") || (Len(QueryRest) == 1))
        {
            FinalPacket = "final";
            return true;
        } else if (Left(QueryRest, 1) == "\\")
            return true;    // \type\\

        // Query looks like:
        //  \type\value
        ClosingSlash = InStr(QueryRest, "\\");
        if (ClosingSlash >= 0)
            QueryValue = Left(QueryRest, ClosingSlash);
        else
            QueryValue = QueryRest;

        QueryRest = Right(Query, Len(Query) - (Len(QueryType) + Len(QueryValue) + 3));
        if (QueryRest == "")
        {
            FinalPacket = "final";
            return true;
        } else
            return true;
    } else {
        return false;
    }
}

function string ParseQuery( IpAddr Addr, coerce string QueryStr, int QueryNum, out int PacketNum )
{
    local string QueryType, QueryValue, QueryRest, ValidationString;
    local bool Result;
    local string FinalPacket;
    
    Result = ParseNextQuery(QueryStr, QueryType, QueryValue, QueryRest, FinalPacket);
    if( !Result )
        return "";

    if( QueryType=="basic" )
    {
        // Ignore.
        Result = true;
    }
    else if( QueryType=="secure" )
    {
        ValidationString = "\\validate\\"$Validate(QueryValue, Query.GameName);
        Result = SendQueryPacket(Addr, ValidationString, QueryNum, ++PacketNum, FinalPacket);
    }
    return QueryRest;
}

// SendQueryPacket is a wrapper for SendText that allows for packet numbering.
function bool SendQueryPacket(IpAddr Addr, coerce string SendString, int QueryNum, int PacketNum, string FinalPacket)
{
    local bool Result;
    if (FinalPacket == "final") {
        SendString = SendString$"\\final\\";
    }
    SendString = SendString$"\\queryid\\"$QueryNum$"."$PacketNum;

    Result = SendText(Addr, SendString);

    return Result;
}

defaultproperties
{
     UpdateMinutes=1
     MasterServerPort=27900
     TargetQueryName=MasterUplink
     RemoteRole=ROLE_None
}

Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames
Class file time: Do 19.5.2005 19:42:14.000 - Creation time: Fr 7.6.2013 13:16:11.310 - Created with UnCodeX