Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames

Botpack.SniperRifle


00001
00002
00003
00004
00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
00213
00214
00215
00216
00217
00218
00219
00220
00221
00222
00223
00224
00225
00226
00227
00228
00229
00230
00231
00232
00233
00234
00235
00236
00237
00238
00239
00240
00241
00242
00243
00244
00245
00246
00247
00248
00249
00250
00251
00252
00253
00254
00255
00256
00257
00258
00259
00260
00261
00262
00263
00264
00265
00266
00267
00268
00269
00270
00271
00272
00273
00274
00275
00276
00277
00278
00279
00280
00281
00282
00283
00284
00285
00286
00287
00288
00289
00290
00291
00292
00293
00294
00295
00296
00297
00298
00299
00300
00301
00302
00303
00304
00305
00306
00307
00308
00309
00310
00311
00312
00313
00314
00315
00316
00317
00318
00319
00320
00321
00322
00323
00324
00325
00326
00327
00328
00329
00330
00331
00332
00333
00334
00335
00336
00337
00338
00339
00340
00341
00342
00343
00344
00345
00346
00347
00348
00349
00350
00351
00352
00353
00354
00355
00356
00357
00358
00359
00360
00361
00362
00363
00364
00365
00366
00367
00368
00369
00370
00371
00372
00373
00374
00375
00376
00377
00378
00379
00380
00381
00382
00383
00384
00385
00386
00387
00388
00389
00390
00391
00392
00393
00394
00395
00396
00397
00398
00399
00400
00401
00402
00403
00404
00405
00406
00407
00408
00409
00410
00411
00412
00413
00414
00415
00416
00417
00418
00419
00420
00421
//=============================================================================
// SniperRifle
// A military redesign of the rifle.
//=============================================================================
class SniperRifle extends TournamentWeapon;

#exec MESH IMPORT MESH=Rifle2m ANIVFILE=MODELS\Rifle2_a.3D DATAFILE=MODELS\Rifle2_d.3D 
#exec MESH ORIGIN MESH=Rifle2m X=0 Y=0 Z=0 YAW=64 PITCH=0 ROLL=0

#exec MESH SEQUENCE MESH=Rifle2m SEQ=All         STARTFRAME=0   NUMFRAMES=75
#exec MESH SEQUENCE MESH=Rifle2m SEQ=Select      STARTFRAME=0   NUMFRAMES=17 RATE=28 GROUP=Select
#exec MESH SEQUENCE MESH=Rifle2m SEQ=Still       STARTFRAME=17  NUMFRAMES=1 
#exec MESH SEQUENCE MESH=Rifle2m SEQ=Fire        STARTFRAME=17  NUMFRAMES=10 RATE=15
#exec MESH SEQUENCE MESH=Rifle2m SEQ=Fire2       STARTFRAME=27  NUMFRAMES=10 RATE=15
#exec MESH SEQUENCE MESH=Rifle2m SEQ=Fire3       STARTFRAME=37  NUMFRAMES=10 RATE=15
#exec MESH SEQUENCE MESH=Rifle2m SEQ=Fire4       STARTFRAME=47  NUMFRAMES=10 RATE=15
#exec MESH SEQUENCE MESH=Rifle2m SEQ=Fire5       STARTFRAME=57  NUMFRAMES=10 RATE=15
#exec MESH SEQUENCE MESH=Rifle2m SEQ=Down        STARTFRAME=67  NUMFRAMES=7

#exec TEXTURE IMPORT NAME=Rifle2a FILE=MODELS\Rifle1.PCX GROUP=Skins LODSET=2
#exec TEXTURE IMPORT NAME=Rifle2b FILE=MODELS\Rifle2.PCX GROUP=Skins LODSET=2
#exec TEXTURE IMPORT NAME=Rifle2c FILE=MODELS\Rifle3.PCX GROUP=Skins LODSET=2
#exec TEXTURE IMPORT NAME=Rifle2d FILE=MODELS\Rifle4.PCX GROUP=Skins LODSET=2
#exec MESHMAP SCALE MESHMAP=Rifle2m X=0.008 Y=0.004 Z=0.016
#exec MESHMAP SETTEXTURE MESHMAP=Rifle2m NUM=0 TEXTURE=Rifle2a
#exec MESHMAP SETTEXTURE MESHMAP=Rifle2m NUM=1 TEXTURE=Rifle2b
#exec MESHMAP SETTEXTURE MESHMAP=Rifle2m NUM=2 TEXTURE=Rifle2c
#exec MESHMAP SETTEXTURE MESHMAP=Rifle2m NUM=3 TEXTURE=Rifle2d

#exec MESH IMPORT MESH=Rifle2mL ANIVFILE=MODELS\Rifle2_a.3D DATAFILE=MODELS\Rifle2_d.3D UnMirror=1
#exec MESH ORIGIN MESH=Rifle2mL X=0 Y=0 Z=0 YAW=64 PITCH=0 ROLL=0

#exec MESH SEQUENCE MESH=Rifle2mL SEQ=All         STARTFRAME=0   NUMFRAMES=75
#exec MESH SEQUENCE MESH=Rifle2mL SEQ=Select      STARTFRAME=0   NUMFRAMES=17 RATE=28 GROUP=Select
#exec MESH SEQUENCE MESH=Rifle2mL SEQ=Still       STARTFRAME=17  NUMFRAMES=1 
#exec MESH SEQUENCE MESH=Rifle2mL SEQ=Fire        STARTFRAME=17  NUMFRAMES=10 RATE=15
#exec MESH SEQUENCE MESH=Rifle2mL SEQ=Fire2       STARTFRAME=27  NUMFRAMES=10 RATE=15
#exec MESH SEQUENCE MESH=Rifle2mL SEQ=Fire3       STARTFRAME=37  NUMFRAMES=10 RATE=15
#exec MESH SEQUENCE MESH=Rifle2mL SEQ=Fire4       STARTFRAME=47  NUMFRAMES=10 RATE=15
#exec MESH SEQUENCE MESH=Rifle2mL SEQ=Fire5       STARTFRAME=57  NUMFRAMES=10 RATE=15
#exec MESH SEQUENCE MESH=Rifle2mL SEQ=Down        STARTFRAME=67  NUMFRAMES=7

#exec MESHMAP SCALE MESHMAP=Rifle2mL X=0.008 Y=0.004 Z=0.016
#exec MESHMAP SETTEXTURE MESHMAP=Rifle2mL NUM=0 TEXTURE=Rifle2a
#exec MESHMAP SETTEXTURE MESHMAP=Rifle2mL NUM=1 TEXTURE=Rifle2b
#exec MESHMAP SETTEXTURE MESHMAP=Rifle2mL NUM=2 TEXTURE=Rifle2c
#exec MESHMAP SETTEXTURE MESHMAP=Rifle2mL NUM=3 TEXTURE=Rifle2d

#exec MESH IMPORT MESH=RiflePick ANIVFILE=MODELS\Riflehand_a.3D DATAFILE=MODELS\Riflehand_d.3D X=0 Y=0 Z=0
#exec MESH ORIGIN MESH=RiflePick X=0 Y=0 Z=0 YAW=64 
#exec MESH SEQUENCE MESH=RiflePick SEQ=All         STARTFRAME=0   NUMFRAMES=1
#exec MESH SEQUENCE MESH=RiflePick SEQ=Still        STARTFRAME=0   NUMFRAMES=1
#exec TEXTURE IMPORT NAME=JRifle2 FILE=MODELS\Rifle.PCX GROUP=Skins LODSET=2
#exec MESHMAP SCALE MESHMAP=RiflePick X=0.1 Y=0.1 Z=0.2
#exec MESHMAP SETTEXTURE MESHMAP=RiflePick NUM=2 TEXTURE=JRifle2

#exec MESH IMPORT MESH=RifleHand ANIVFILE=MODELS\Riflehand_a.3D DATAFILE=MODELS\Riflehand_d.3D X=0 Y=0 Z=0
#exec MESH ORIGIN MESH=RifleHand X=15 Y=170 Z=-30 YAW=64 PITCH=0 ROLL=0
#exec MESH SEQUENCE MESH=RifleHand SEQ=All  STARTFRAME=0  NUMFRAMES=1
#exec MESHMAP SCALE MESHMAP=RifleHand X=0.07 Y=0.07 Z=0.14
#exec MESHMAP SETTEXTURE MESHMAP=RifleHand NUM=2 TEXTURE=JRifle2

#exec TEXTURE IMPORT NAME=MuzzleFlash2 FILE=TEXTURES\NewMuz2.PCX GROUP="Rifle" MIPS=OFF LODSET=2
#exec TEXTURE IMPORT NAME=IconRifle FILE=TEXTURES\HUD\WpnRifle.PCX GROUP="Icons" MIPS=OFF
#exec TEXTURE IMPORT NAME=UseRifle FILE=TEXTURES\HUD\UseRifle.PCX GROUP="Icons" MIPS=OFF
#exec TEXTURE IMPORT NAME=RReticle FILE=TEXTURES\rifleret.PCX GROUP="Icons" MIPS=OFF FLAGS=2 LODSET=2

#exec AUDIO IMPORT FILE="Sounds\SniperRifle\SniperFire.wav" NAME="SniperFire" GROUP="SniperRifle"

#exec MESH IMPORT MESH=muzzsr3 ANIVFILE=MODELS\muzzle2_a.3d DATAFILE=MODELS\Muzzle2_d.3d X=0 Y=0 Z=0
#exec MESH LODPARAMS MESH=muzzsr3 MINVERTS=8 STRENGTH=0.7 ZDISP=800.0
#exec MESH ORIGIN MESH=muzzsr3 X=0 Y=980 Z=-75 YAW=64
#exec MESH SEQUENCE MESH=muzzsr3 SEQ=All                      STARTFRAME=0 NUMFRAMES=3
#exec MESH SEQUENCE MESH=muzzsr3 SEQ=Shoot                   STARTFRAME=0 NUMFRAMES=3
#exec MESHMAP NEW   MESHMAP=muzzsr3 MESH=muzzsr3
#exec MESHMAP SCALE MESHMAP=muzzsr3 X=0.04 Y=0.1 Z=0.08
#exec TEXTURE IMPORT NAME=Muzzy3 FILE=MODELS\Muzzy3.PCX GROUP=Skins

var int NumFire;
var name FireAnims[5];
var vector OwnerLocation;
var float StillTime, StillStart;

simulated function PostRender( canvas Canvas )
{
    local PlayerPawn P;
    local float Scale;

    Super.PostRender(Canvas);
    P = PlayerPawn(Owner);
    if ( (P != None) && (P.DesiredFOV != P.DefaultFOV) ) 
    {
        bOwnsCrossHair = true;
        Scale = Canvas.ClipX/640;
        Canvas.SetPos(0.5 * Canvas.ClipX - 128 * Scale, 0.5 * Canvas.ClipY - 128 * Scale );
        if ( Level.bHighDetailMode )
            Canvas.Style = ERenderStyle.STY_Translucent;
        else
            Canvas.Style = ERenderStyle.STY_Normal;
        Canvas.DrawIcon(Texture'RReticle', Scale);
        Canvas.SetPos(0.5 * Canvas.ClipX + 64 * Scale, 0.5 * Canvas.ClipY + 96 * Scale);
        Canvas.DrawColor.R = 0;
        Canvas.DrawColor.G = 255;
        Canvas.DrawColor.B = 0;
        Scale = P.DefaultFOV/P.DesiredFOV;
        Canvas.DrawText("X"$int(Scale)$"."$int(10 * Scale - 10 * int(Scale)));
    }
    else
        bOwnsCrossHair = false;
}

function float RateSelf( out int bUseAltMode )
{
    local float dist;

    if ( AmmoType.AmmoAmount <=0 )
        return -2;

    bUseAltMode = 0;
    if ( (Bot(Owner) != None) && Bot(Owner).bSniping )
        return AIRating + 1.15;
    if (  Pawn(Owner).Enemy != None )
    {
        dist = VSize(Pawn(Owner).Enemy.Location - Owner.Location);
        if ( dist > 1200 )
        {
            if ( dist > 2000 )
                return (AIRating + 0.75);
            return (AIRating + FMin(0.0001 * dist, 0.45)); 
        }
    }
    return AIRating;
}

// set which hand is holding weapon
function setHand(float Hand)
{
    Super.SetHand(Hand);
    if ( Hand == 1 )
        Mesh = mesh(DynamicLoadObject("Botpack.Rifle2mL", class'Mesh'));
    else
        Mesh = mesh'Rifle2m';
}

simulated function PlayFiring()
{
    local int r;

    PlayOwnedSound(FireSound, SLOT_None, Pawn(Owner).SoundDampening*3.0);
    PlayAnim(FireAnims[Rand(5)],0.5 + 0.5 * FireAdjust, 0.05);

    if ( (PlayerPawn(Owner) != None) 
        && (PlayerPawn(Owner).DesiredFOV == PlayerPawn(Owner).DefaultFOV) )
        bMuzzleFlash++;
}


simulated function bool ClientAltFire( float Value )
{
    GotoState('Zooming');
    return true;
}

function AltFire( float Value )
{
    ClientAltFire(Value);
}

///////////////////////////////////////////////////////
state NormalFire
{
    function EndState()
    {
        Super.EndState();
        OldFlashCount = FlashCount;
    }
        
Begin:
    FlashCount++;
}

function Timer()
{
    local actor targ;
    local float bestAim, bestDist;
    local vector FireDir;
    local Pawn P;

    bestAim = 0.95;
    P = Pawn(Owner);
    if ( P == None )
    {
        GotoState('');
        return;
    }
    if ( VSize(P.Location - OwnerLocation) < 6 )
        StillTime += FMin(2.0, Level.TimeSeconds - StillStart);

    else
        StillTime = 0;
    StillStart = Level.TimeSeconds;
    OwnerLocation = P.Location;
    FireDir = vector(P.ViewRotation);
    targ = P.PickTarget(bestAim, bestDist, FireDir, Owner.Location);
    if ( Pawn(targ) != None )
    {
        SetTimer(1 + 4 * FRand(), false);
        bPointing = true;
        Pawn(targ).WarnTarget(P, 200, FireDir);
    }
    else 
    {
        SetTimer(0.4 + 1.6 * FRand(), false);
        if ( (P.bFire == 0) && (P.bAltFire == 0) )
            bPointing = false;
    }
}   

function ProcessTraceHit(Actor Other, Vector HitLocation, Vector HitNormal, Vector X, Vector Y, Vector Z)
{
    local UT_Shellcase s;

    s = Spawn(class'UT_ShellCase',, '', Owner.Location + CalcDrawOffset() + 30 * X + (2.8 * FireOffset.Y+5.0) * Y - Z * 1);
    if ( s != None ) 
    {
        s.DrawScale = 2.0;
        s.Eject(((FRand()*0.3+0.4)*X + (FRand()*0.2+0.2)*Y + (FRand()*0.3+1.0) * Z)*160);              
    }
    if (Other == Level) 
        Spawn(class'UT_HeavyWallHitEffect',,, HitLocation+HitNormal, Rotator(HitNormal));
    else if ( (Other != self) && (Other != Owner) && (Other != None) ) 
    {
        if ( Other.bIsPawn )
            Other.PlaySound(Sound 'ChunkHit',, 4.0,,100);
        if ( Other.bIsPawn && (HitLocation.Z - Other.Location.Z > 0.62 * Other.CollisionHeight) 
            && (instigator.IsA('PlayerPawn') || (instigator.IsA('Bot') && !Bot(Instigator).bNovice)) )
            Other.TakeDamage(100, Pawn(Owner), HitLocation, 35000 * X, AltDamageType);
        else
            Other.TakeDamage(45,  Pawn(Owner), HitLocation, 30000.0*X, MyDamageType);   
        if ( !Other.bIsPawn && !Other.IsA('Carcass') )
            spawn(class'UT_SpriteSmokePuff',,,HitLocation+HitNormal*9); 
    }
}

function Finish()
{
    if ( (Pawn(Owner).bFire!=0) && (FRand() < 0.6) )
        Timer();
    Super.Finish();
}

function TraceFire( float Accuracy )
{
    local vector HitLocation, HitNormal, StartTrace, EndTrace, X,Y,Z;
    local actor Other;
    local Pawn PawnOwner;

    PawnOwner = Pawn(Owner);

    Owner.MakeNoise(PawnOwner.SoundDampening);
    GetAxes(PawnOwner.ViewRotation,X,Y,Z);
    StartTrace = Owner.Location + PawnOwner.Eyeheight * Z; 
    AdjustedAim = PawnOwner.AdjustAim(1000000, StartTrace, 2*AimError, False, False);   
    X = vector(AdjustedAim);
    EndTrace = StartTrace + 10000 * X; 
    Other = PawnOwner.TraceShot(HitLocation,HitNormal,EndTrace,StartTrace);
    ProcessTraceHit(Other, HitLocation, HitNormal, X,Y,Z);
}


state Idle
{
    function Fire( float Value )
    {
        if ( AmmoType == None )
        {
            // ammocheck
            GiveAmmo(Pawn(Owner));
        }
        if (AmmoType.UseAmmo(1))
        {
            GotoState('NormalFire');
            bCanClientFire = true;
            bPointing=True;
            if ( Owner.IsA('Bot') )
            {
                // simulate bot using zoom
                if ( Bot(Owner).bSniping && (FRand() < 0.65) )
                    AimError = AimError/FClamp(StillTime, 1.0, 8.0);
                else if ( VSize(Owner.Location - OwnerLocation) < 6 )
                    AimError = AimError/FClamp(0.5 * StillTime, 1.0, 3.0);
                else
                    StillTime = 0;
            }
            Pawn(Owner).PlayRecoil(FiringSpeed);
            TraceFire(0.0);
            AimError = Default.AimError;
            ClientFire(Value);
        }
    }


    function BeginState()
    {
        bPointing = false;
        SetTimer(0.4 + 1.6 * FRand(), false);
        Super.BeginState();
    }

    function EndState()
    {   
        SetTimer(0.0, false);
        Super.EndState();
    }
    
Begin:
    bPointing=False;
    if ( AmmoType.AmmoAmount<=0 ) 
        Pawn(Owner).SwitchToBestWeapon();  //Goto Weapon that has Ammo
    if ( Pawn(Owner).bFire!=0 ) Fire(0.0);
    Disable('AnimEnd');
    PlayIdleAnim();
}

///////////////////////////////////////////////////////
state Zooming
{
    simulated function Tick(float DeltaTime)
    {
        if ( Pawn(Owner).bAltFire == 0 )
        {
            if ( (PlayerPawn(Owner) != None) && PlayerPawn(Owner).Player.IsA('ViewPort') )
                PlayerPawn(Owner).StopZoom();
            SetTimer(0.0,False);
            GoToState('Idle');
        }
    }

    simulated function BeginState()
    {
        if ( Owner.IsA('PlayerPawn') )
        {
            if ( PlayerPawn(Owner).Player.IsA('ViewPort') )
                PlayerPawn(Owner).ToggleZoom();
            SetTimer(0.2,True);
        }
        else
        {
            Pawn(Owner).bFire = 1;
            Pawn(Owner).bAltFire = 0;
            Global.Fire(0);
        }
    }
}

///////////////////////////////////////////////////////////
simulated function PlayIdleAnim()
{
    if ( Mesh != PickupViewMesh )
        PlayAnim('Still',1.0, 0.05);
}

defaultproperties
{
     FireAnims(0)=Fire
     FireAnims(1)=Fire2
     FireAnims(2)=Fire3
     FireAnims(3)=Fire4
     FireAnims(4)=Fire5
     WeaponDescription="Classification: Long Range Ballistic\n\nRegular Fire: Fires a high powered bullet. Can kill instantly when applied to the cranium of opposing forces. \n\nSecondary Fire: Zooms the rifle in, up to eight times normal vision. Allows for extreme precision from hundreds of yards away.\n\nTechniques: Great for long distance headshots!"
     AmmoName=Class'Botpack.BulletBox'
     PickupAmmoCount=8
     bInstantHit=True
     bAltInstantHit=True
     FiringSpeed=1.800000
     FireOffset=(Y=-5.000000,Z=-2.000000)
     MyDamageType=shot
     AltDamageType=Decapitated
     shakemag=400.000000
     shaketime=0.150000
     shakevert=8.000000
     AIRating=0.540000
     RefireRate=0.600000
     AltRefireRate=0.300000
     FireSound=Sound'Botpack.SniperRifle.SniperFire'
     SelectSound=Sound'UnrealI.Rifle.RiflePickup'
     DeathMessage="%k put a bullet through %o's head."
     NameColor=(R=0,G=0)
     bDrawMuzzleFlash=True
     MuzzleScale=1.000000
     FlashY=0.110000
     FlashO=0.014000
     FlashC=0.031000
     FlashLength=0.013000
     FlashS=256
     MFTexture=Texture'Botpack.Rifle.MuzzleFlash2'
     AutoSwitchPriority=5
     InventoryGroup=10
     PickupMessage="You got a Sniper Rifle."
     ItemName="Sniper Rifle"
     PlayerViewOffset=(X=5.000000,Y=-1.600000,Z=-1.700000)
     PlayerViewMesh=LodMesh'Botpack.Rifle2m'
     PlayerViewScale=2.000000
     BobDamping=0.975000
     PickupViewMesh=LodMesh'Botpack.RiflePick'
     ThirdPersonMesh=LodMesh'Botpack.RifleHand'
     StatusIcon=Texture'Botpack.Icons.UseRifle'
     bMuzzleFlashParticles=True
     MuzzleFlashStyle=STY_Translucent
     MuzzleFlashMesh=LodMesh'Botpack.muzzsr3'
     MuzzleFlashScale=0.100000
     MuzzleFlashTexture=Texture'Botpack.Skins.Muzzy3'
     PickupSound=Sound'UnrealShare.Pickups.WeaponPickup'
     Icon=Texture'Botpack.Icons.UseRifle'
     Rotation=(Roll=-1536)
     Mesh=LodMesh'Botpack.RiflePick'
     bNoSmooth=False
     CollisionRadius=32.000000
     CollisionHeight=8.000000
}

Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames
Class file time: Do 19.5.2005 19:42:14.000 - Creation time: Fr 7.6.2013 13:16:00.967 - Created with UnCodeX